mirror of
https://github.com/google/nomulus
synced 2026-06-09 16:33:02 +00:00
Ben McIlwain
1cd6026151
This commit reverts changes from PR #3068 that swapped 'npm run build' for 'npx ng build' while attempting to dynamically set the '--output-path' via the CLI. Passing '--output-path' on the command line overrides the entire 'outputPath' configuration object in angular.json. Because the new Angular 18 Application Builder (esbuild) nests outputs inside a 'browser/' directory by default, overriding the configuration bypassed the 'browser: ""' flattening property, causing all client assets to be nested deeper than expected. This resulted in empty deployments because downstream tasks (like Jetty's copyConsole and the deployment tar scripts) expected the assets to be completely flat. By removing the '--output-path' override from the 'npx ng build' calls, the Angular CLI once again respects angular.json, flattens the output into 'staged/dist/', and the restored 'doLast' block successfully copies the artifacts where they belong.
111 lines
3.5 KiB
Groovy
111 lines
3.5 KiB
Groovy
// Copyright 2024 The Nomulus Authors. All Rights Reserved.
|
|
//
|
|
// Licensed under the Apache License, Version 2.0 (the "License");
|
|
// you may not use this file except in compliance with the License.
|
|
// You may obtain a copy of the License at
|
|
//
|
|
// http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
// Unless required by applicable law or agreed to in writing, software
|
|
// distributed under the License is distributed on an "AS IS" BASIS,
|
|
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
// See the License for the specific language governing permissions and
|
|
// limitations under the License.
|
|
def consoleDir = "${rootDir}/console-webapp"
|
|
def projectParam = "--project=${rootProject.gcpProject}"
|
|
|
|
clean {
|
|
delete "${consoleDir}/node_modules"
|
|
delete "${consoleDir}/staged/dist"
|
|
}
|
|
|
|
task npmInstallDeps(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'i', '--no-audit', '--no-fund', '--loglevel=error'
|
|
}
|
|
|
|
task runConsoleWebappLocally(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'start:dev'
|
|
}
|
|
|
|
task runConsoleWebappUnitTests(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'test'
|
|
}
|
|
|
|
task buildConsoleWebapp(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npx'
|
|
def configuration = project.getProperty('configuration')
|
|
args 'ng', 'build', '--base-href=/console/', "--configuration=${configuration}", "--output-path=staged/dist"
|
|
doFirst {
|
|
println "Building console for environment: ${configuration}"
|
|
}
|
|
}
|
|
|
|
task buildConsoleForAll() {}
|
|
|
|
def createConsoleTask = { env ->
|
|
project.tasks.register("buildConsoleFor${env.capitalize()}", Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npx'
|
|
args 'ng', 'build', '--base-href=/console/', "--configuration=${env}"
|
|
doFirst {
|
|
println "Building console for environment: ${env}"
|
|
}
|
|
doLast {
|
|
copy {
|
|
from "${consoleDir}/staged/dist/"
|
|
into "${consoleDir}/staged/console-${env}"
|
|
}
|
|
delete "${consoleDir}/staged/dist"
|
|
}
|
|
dependsOn(tasks.npmInstallDeps)
|
|
}
|
|
project.tasks.register("deleteConsoleFor${env.capitalize()}", Delete) {
|
|
delete "${consoleDir}/staged/console-${env}"
|
|
}
|
|
tasks.named('clean') {
|
|
dependsOn(tasks.named("deleteConsoleFor${env.capitalize()}"))
|
|
}
|
|
tasks.named('buildConsoleForAll') {
|
|
dependsOn(tasks.named("buildConsoleFor${env.capitalize()}"))
|
|
}
|
|
}
|
|
|
|
['alpha', 'crash', 'qa', 'sandbox', 'production'].forEach {env ->
|
|
createConsoleTask(env)
|
|
}
|
|
|
|
// Force an order so we don't run these tasks in parallel.
|
|
tasks.buildConsoleForCrash.mustRunAfter(tasks.buildConsoleForAlpha)
|
|
tasks.buildConsoleForQa.mustRunAfter(tasks.buildConsoleForCrash)
|
|
tasks.buildConsoleForSandbox.mustRunAfter(tasks.buildConsoleForQa)
|
|
tasks.buildConsoleForProduction.mustRunAfter(tasks.buildConsoleForSandbox)
|
|
// This task must run last, otherwise the previous tasks will have deleted the "dist" folder.
|
|
tasks.buildConsoleWebapp.mustRunAfter(tasks.buildConsoleForProduction)
|
|
|
|
task applyFormatting(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'prettify'
|
|
}
|
|
|
|
task checkFormatting(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'prettify:check'
|
|
}
|
|
|
|
tasks.buildConsoleWebapp.dependsOn(tasks.npmInstallDeps)
|
|
tasks.runConsoleWebappUnitTests.dependsOn(tasks.npmInstallDeps)
|
|
tasks.applyFormatting.dependsOn(tasks.npmInstallDeps)
|
|
tasks.checkFormatting.dependsOn(tasks.npmInstallDeps)
|
|
tasks.build.dependsOn(tasks.checkFormatting)
|
|
tasks.build.dependsOn(tasks.runConsoleWebappUnitTests)
|
|
tasks.build.dependsOn(tasks.buildConsoleForAll)
|