mirror of
https://github.com/google/nomulus
synced 2026-06-01 04:26:34 +00:00
5286b1a0dc
This commit dramatically optimizes the local Gradle build time, shaving over 5 minutes off a full build execution: - Instrumented the build to identify fragileTest taking > 3 minutes. - Refactored TestServer.java to dynamically bind to ephemeral port 0, resolving race conditions. - Updated UploadBsaUnavailableDomainsActionTest to use the thread-safe TestServer, allowing it to run in parallel. - Removed outdated exclusions for HostInfoFlowTest and RegistryPipelineWorkerInitializerTest. - Moved these tests to the highly parallelized standardTest suite. - Removed the redundant sqlIntegrationTest execution from the standard test phase. - Stripped heavy Docker (buildNomulusImage) and 5x frontend (buildConsoleForAll) staging dependencies from the standard build task, ensuring they are only run when explicitly deployed.
95 lines
2.9 KiB
Groovy
95 lines
2.9 KiB
Groovy
// Copyright 2024 The Nomulus Authors. All Rights Reserved.
|
|
//
|
|
// Licensed under the Apache License, Version 2.0 (the "License");
|
|
// you may not use this file except in compliance with the License.
|
|
// You may obtain a copy of the License at
|
|
//
|
|
// http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
// Unless required by applicable law or agreed to in writing, software
|
|
// distributed under the License is distributed on an "AS IS" BASIS,
|
|
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
// See the License for the specific language governing permissions and
|
|
// limitations under the License.
|
|
def consoleDir = "${rootDir}/console-webapp"
|
|
def projectParam = "--project=${rootProject.gcpProject}"
|
|
|
|
clean {
|
|
delete "${consoleDir}/node_modules"
|
|
delete "${consoleDir}/staged/dist"
|
|
}
|
|
|
|
task npmInstallDeps(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'i', '--no-audit', '--no-fund', '--loglevel=error'
|
|
}
|
|
|
|
task runConsoleWebappLocally(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'start:dev'
|
|
}
|
|
|
|
task runConsoleWebappUnitTests(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'test'
|
|
}
|
|
|
|
task buildConsoleWebapp(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npx'
|
|
def configuration = project.getProperty('configuration')
|
|
args 'ng', 'build', '--base-href=/console/', "--configuration=${configuration}", "--output-path=staged/dist"
|
|
doFirst {
|
|
println "Building console for environment: ${configuration}"
|
|
}
|
|
}
|
|
|
|
task buildConsoleForAll() {}
|
|
|
|
def createConsoleTask = { env ->
|
|
project.tasks.register("buildConsoleFor${env.capitalize()}", Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npx'
|
|
args 'ng', 'build', '--base-href=/console/', "--configuration=${env}", "--output-path=staged/console-${env}"
|
|
doFirst {
|
|
println "Building console for environment: ${env}"
|
|
}
|
|
dependsOn(tasks.npmInstallDeps)
|
|
}
|
|
project.tasks.register("deleteConsoleFor${env.capitalize()}", Delete) {
|
|
delete "${consoleDir}/staged/console-${env}"
|
|
}
|
|
tasks.named('clean') {
|
|
dependsOn(tasks.named("deleteConsoleFor${env.capitalize()}"))
|
|
}
|
|
tasks.named('buildConsoleForAll') {
|
|
dependsOn(tasks.named("buildConsoleFor${env.capitalize()}"))
|
|
}
|
|
}
|
|
|
|
['alpha', 'crash', 'qa', 'sandbox', 'production'].forEach {env ->
|
|
createConsoleTask(env)
|
|
}
|
|
|
|
task applyFormatting(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'prettify'
|
|
}
|
|
|
|
task checkFormatting(type: Exec) {
|
|
workingDir "${consoleDir}/"
|
|
executable 'npm'
|
|
args 'run', 'prettify:check'
|
|
}
|
|
|
|
tasks.buildConsoleWebapp.dependsOn(tasks.npmInstallDeps)
|
|
tasks.runConsoleWebappUnitTests.dependsOn(tasks.npmInstallDeps)
|
|
tasks.applyFormatting.dependsOn(tasks.npmInstallDeps)
|
|
tasks.checkFormatting.dependsOn(tasks.npmInstallDeps)
|
|
tasks.build.dependsOn(tasks.checkFormatting)
|
|
tasks.build.dependsOn(tasks.runConsoleWebappUnitTests)
|