Add new testcase: multiv05.at:

tests/Makefile.am

@@ -83,6 +83,7 @@ TESTSUITE_AT = \
  multiv02.at\
  multiv03.at\
  multiv04.at\
+ multiv05.at\
  old.at\
  options.at\
  options02.at\

tests/multiv05.at

@@ -0,0 +1,67 @@
+# Process this file with autom4te to create testsuite. -*- Autotest -*-
+
+# Test suite for GNU tar.
+# Copyright (C) 2006 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
+# 02110-1301, USA.
+
+# Up to version 1.15.91 tar was unable to recognize all volumes
+# given after an aout-of-sync volume.
+# Reported by: Joerg Weilbier <gnu@weilbier.net>
+# References: <200610011952.29880.gnu@weilbier.net>
+
+AT_SETUP([Restoring after an out of sync folume])
+AT_KEYWORDS([multivolume multiv multiv05 sync])
+m4_define([FILELIST],[jeden,dwa,trzy,cztery,piec,szesc])
+
+AT_TAR_CHECK([
+exec <&-
+
+m4_foreach([f],
+  [FILELIST],
+  [genfile --length 250k --file f
+])
+
+echo Creating archive
+tar -c -M -L 502 -f a.tar -f b.tar -f c.tar m4_foreach([f],[FILELIST],f )
+echo separator
+mkdir bak
+mv m4_foreach([f],[FILELIST],f )bak
+tar -vxM -f a.tar -f c.tar -f b.tar -f c.tar 
+m4_foreach([f],
+  [FILELIST],
+  [echo Diffing f
+   cmp bak/f f || exit 1
+])],
+[0],
+[Creating archive
+separator]
+m4_foreach([file],
+  [FILELIST],
+  [file
+])dnl
+m4_foreach([file],
+  [FILELIST],
+  [Diffing file
+])dnl
+,
+[tar: `trzy' is not continued on this volume
+],[],[], [gnu])
+
+AT_CLEANUP
+
+
+

tests/testsuite.at

@@ -147,6 +147,7 @@ m4_include([multiv01.at])
 m4_include([multiv02.at])
 m4_include([multiv03.at])
 m4_include([multiv04.at])
+m4_include([multiv05.at])
 
 m4_include([old.at])